Matriks Formülleri

**ugur** · 13-03-2017, 12:26

Originally Posted by atikurt

evet çözüldü ama buseferde indikatör ilerlemede sıkıntı yaşamaz mı.

Hayır periyod kapanışını bekler indikatör..

Mesela 5 dakikalık periyot ile grafiği takip ediyorsanız,

5 dakikanın bitiminde indikatör değeri kapanış değeri ile güncellenir..

Ufuk hocam zaten halletmiş, ayrıca..

**ertan** · 13-03-2017, 13:17

Originally Posted by kafkaf

uufuk hocam,

ideal'de fxsniper diye bir indikatör mevcut. Metastock ya da matriks'te bu indikatörün karşılığı var mıdır? Siz kaynak koda rastladınız mı? Tşk.

ergodic veya macd türevlerine bakabilirsiniz. görüntü olarak benzerlikler göreceksiniz

**kafkaf** · 13-03-2017, 14:06

Originally Posted by ertan

ergodic veya macd türevlerine bakabilirsiniz. görüntü olarak benzerlikler göreceksiniz

Teşekkür, bir göz atayım.

**uufuk** · 13-03-2017, 19:39

Originally Posted by kafkaf

Hocam google'den baktım ancak, ideal platformundakine hiç biri benzemiyor. Bu yüzden size sormuştum, belki daha önce karşılaşmışsınızdır diye. Sizin tecrübeniz bizden daha fazla. Denk gelirsem paylaşırım. Tşk.

https://www.forexstrategiesresources...ic-cci-system/

[IMG]

[/IMG]

[IMG]

[/IMG]

İdeal datası 2013de kalmış(offline kullandım),tüm grafikleri o tarihe çektim...
USDTRY tüm platformlarda oldugu ve yaklaşık eşit olacagından tercih ettim..

Formulu bul...Kullan...

pds1:=10; pds2:=2;
Mov(Mov(C-Ref(C,-1),pds1,e),pds2,e)/Mov(Mov(Abs(C-Ref(C,-1)),pds1,e),pds2,e)*500

**uufuk** · 13-03-2017, 20:02

Originally Posted by erden

Ufuk Bey 10 günlük hareketli ortalamanın 50 günlüğü yukarı kestiği aynı zamanda son üçgünde hacmin arttığı förmülü yazarmısınız matriks için saygılar

Özel mesaj,ama özelligi yok...
Bizim kaloferci dostumuzun arşivinde bu gün bu sorunun cevabı resimli olarak vardı.
Şimdi bu soruyu soran dostu sorgulamak gerekir...

**kafkaf** · 13-03-2017, 21:01

uufuk hocam,
yemek yedim, bilgisayar başına geçtim. Google hazretlerine danışmadan önce senin paylaşımını gördüm. Eline sağlık

Yardımın için çok teşekkür ederim.

Originally Posted by uufuk

https://www.forexstrategiesresources...ic-cci-system/

[IMG]

[/IMG]

[IMG]

[/IMG]

İdeal datası 2013de kalmış(offline kullandım),tüm grafikleri o tarihe çektim...
USDTRY tüm platformlarda oldugu ve yaklaşık eşit olacagından tercih ettim..

Formulu bul...Kullan...

pds1:=10; pds2:=2;
Mov(Mov(C-Ref(C,-1),pds1,e),pds2,e)/Mov(Mov(Abs(C-Ref(C,-1)),pds1,e),pds2,e)*500

**uufuk** · 15-03-2017, 22:53

Originally Posted by xxx

Selam uufuk hocam

Üstadım
http://tradingtuitions.com/afl-of-th...kout-system-2/
bu sistemi matrikse çevirmek istiyorum ancak kısıtlı ingilizce ve bilgi olunca translate türkçesi ile de pek mümkün olmuyor
kodun tamamı buraya sığmadığı için yazamadım AFL Code diye geçiyor yardımcı olursanız sevinirim

Dostumuzun istegi üzerine,Amibroker'den Matriks'e çevirdim ..
Bu kadar uzun kod nasıl davranır,iyi bir şeymi degilmi karışmam...
İnceleyip fikir edinmek,karar vermek sizden...

Amibroker

Kod:

//------------------------------------------------------
//
//  Formula Name:    Intraday Opening Range Breakout system
//  Author/Uploader: Trading Tuitions
//  E-mail:          [email protected]
//  Website:         www.tradingtuitions.com
//------------------------------------------------------


function ParamOptimize( pname, defaultval, minv, maxv, step ) 
{ 
return Optimize( pname, 
Param( pname, defaultval, minv, maxv, step ), 
minv, maxv, step ); 
} 
 
_SECTION_BEGIN("Intraday Opening Range Breakout system");  

SetOption( "InitialEquity", 200000);
SetOption("FuturesMode" ,True);
SetOption("MinShares",1);
SetOption("CommissionMode",2);
SetOption("CommissionAmount",50);
SetOption("AccountMargin",10);
SetOption("RefreshWhenCompleted",True);
SetPositionSize(150,spsShares);
SetOption( "AllowPositionShrinking", True );
 
//--Intraday time frame  
TimeFrameSet(in5Minute); 
TimeFrameInMinutes = 5; 
 
//--Define all params  
EntryBufferPct = ParamOptimize("Entry Buffer %", 0, 0, 2, 0.1); 
SLPct = ParamOptimize("SL %", 0.5, 0.5, 2, 0.5); 
TargetPct = ParamOptimize("Target %", 3, 0, 3, 0.5); 
MaxTarget = 100; 
TargetPct = IIf(TargetPct == 0, MaxTarget, TargetPct);  
EntryTimeStart = ParamOptimize("Entry Time Start (Minutes)", 55, 5, 120, 5); 
EntryBarStart = floor(EntryTimeStart/TimeFrameInMinutes) - 1; 
EntryTimeEnd = ParamOptimize("Entry Time End (Minutes)", 70, 10, 300, 10); 
EntryBarEnd = floor(EntryTimeEnd/TimeFrameInMinutes) - 1; 
EntryBarEnd = IIf(EntryBarEnd < EntryBarStart, EntryBarStart, EntryBarEnd);   
 
//--Plot Price Candle Chart 
SetChartOptions(0,chartShowArrows|chartShowDates); 
_N(Title = StrFormat("{{NAME}} - {{INTERVAL}} {{DATE}} Open %g, Hi %g, Lo %g, Close %g (%.1f%%) {{VALUES}}", O, H, L, C, SelectedValue( ROC( C, 1 ) ) )); 
Plot( Close, "Price", colorWhite, styleCandle );
 
//--New Day & Time. End Day & Time . End Day & Time is null till end of day 1   
NewDay = (Day()!= Ref(Day(), -1)) OR BarIndex() == 0;  
printf("\n NewDay  : " + NewDay );  
EndDay = (Day()!= Ref(Day(), 1));  
printf("\n EndDay  : " + EndDay ); 
FirstBarTime = ValueWhen(NewDay,TimeNum(),1);  
EndTime = ValueWhen(EndDay,TimeNum(),1); 
SquareOffTime = EndTime; 
 
//--Calculate ORB, and SL 
HighestOfDay = HighestSince(NewDay,H,1);  
LowestOfDay = LowestSince(NewDay,L,1);  
ORBH = ValueWhen(NewDay,HighestOfDay ,1) * (1 + (EntryBufferPct/100));  
ORBL = ValueWhen(NewDay,LowestOfDay ,1) * (1 - (EntryBufferPct/100));  

 
//--Find Buy, Sell, Short & Cover Signals 
BarsSinceNewDay = BarsSince(NewDay);  
BuySignal = (H >= ORBH) AND (BarsSinceNewDay  > EntryBarStart);  
printf("\nBuySignal : " + BuySignal );  
ShortSignal = (L <= ORBL) AND (BarsSinceNewDay  > EntryBarStart) ;  
printf("\nShortSignal  : " + ShortSignal );  
BarsSinceLastBuySignal = (BarsSince(Ref(BuySignal,-1)) + 1); 
BarsSinceLastShortSignal = (BarsSince(Ref(ShortSignal,-1)) + 1); 
BarsSinceLastEntrySignal = Min(BarsSinceLastBuySignal, BarsSinceLastShortSignal); 
BothEntrySignalsNull = IsNull(BarsSinceLastBuySignal) AND IsNull(BarsSinceLastShortSignal); //true for start of Day 1 
printf("\n\nBarsSinceNewDay : " + BarsSinceNewDay );  
printf("\nBarsSinceLastBuySignal : " + BarsSinceLastBuySignal );  
printf("\nBarsSinceLastShortSignal : " + BarsSinceLastShortSignal );  
printf("\n BarsSinceLastEntrySignal : " + BarsSinceLastEntrySignal);  
Buy = (H >= ORBH) AND (BarsSinceNewDay  > EntryBarStart) AND (BarsSinceNewDay <= EntryBarEnd) AND ((BarsSinceNewDay < BarsSinceLastEntrySignal) OR BothEntrySignalsNull );  
Short = (L <= ORBL) AND (BarsSinceNewDay  > EntryBarStart) AND (BarsSinceNewDay <= EntryBarEnd) AND ((BarsSinceNewDay < BarsSinceLastEntrySignal) OR BothEntrySignalsNull );  
BuyPrice = IIf(Buy, Max(ORBH,O), Null);  
ShortPrice = IIf(Short, Min(ORBL,Open), Null);  

ORBHSL = ValueWhen(BuyPrice,BuyPrice) * (1-(SLPct/100));   
ORBLSL = ValueWhen(ShortPrice,ShortPrice) * (1+(SLPct/100)); 
ORBHTarget = ValueWhen(BuyPrice,BuyPrice) * (1+(TargetPct/100)); 
ORBLTarget = ValueWhen(ShortPrice,ShortPrice) * (1-(TargetPct/100)); 

Sell = (L <= ORBHSL) OR (H >= ORBHTarget) OR (TimeNum() > SquareOffTime-1) AND (BarsSinceNewDay > BarsSinceLastBuySignal);  
Cover = (H >= ORBLSL) OR (L <= ORBLTarget) OR (TimeNum() > SquareOffTime-1) AND (BarsSinceNewDay > BarsSinceLastShortSignal);  

SellPrice = IIf(Sell, IIf(H >= ORBHTarget, ORBHTarget, Max(ORBHSL, L)), Null);  
CoverPrice = IIf(Cover, IIf(L <= ORBLTarget, ORBLTarget, Min(ORBLSL, H)), Null);  

printf("\nBuy : " + Buy );  
printf("\nSell : " + Sell );  
printf("\nShort : " + Short );  
printf("\nCover : " + Cover );  

printf("\nORBH : " + ORBH );  
printf("\nORBL : " + ORBL );  
printf("\nBuyPrice : " + BuyPrice );  
printf("\nShortPrice : " + ShortPrice );  

printf("\nORBHSL : " + ORBHSL );  
printf("\nORBLSL : " + ORBLSL );  
printf("\nORBHTarget : " + ORBHTarget );  
printf("\nORBLTarget : " + ORBLTarget );  
 
//--Handle if ORB broken both sides on same bar 
//--And remove duplicate Sell & Cover signals, since ExRem did not work as needed when Buy & Sell on same bar 
orbBothSides = IIf(Buy AND Short, 1, 0);  
Buy = IIf(orbBothSides AND C <= O, 0, Buy);  
Short = IIf(orbBothSides AND C > O, 0, Short);  
Sell = IIf(orbBothSides AND C > O AND (L <= ORBHSL), 1, Sell);  
Sell = IIf((BarsSince(Buy) < (BarsSince(Ref(Sell,-1))+1)) OR (BarsSince(Buy) AND IsNull(BarsSince(Ref(Sell,-1)))),Sell,0); 
Cover = IIf(orbBothSides AND C <= O AND (H >= ORBLSL), 1, Cover);  
Cover = IIf((BarsSince(Short) < (BarsSince(Ref(Cover,-1))+1)) OR (BarsSince(Short) AND IsNull(BarsSince(Ref(Cover,-1)))),Cover,0); 


//Plot(IIf(BarsSinceNewDay > BarsSinceLastBuySignal,ORBHSL,NULL),"BuyStopLoss",colorRed,styleDashed); 
//Plot(IIf(BarsSinceNewDay > BarsSinceLastShortSignal,ORBLSL,NULL),"SellStopLoss",colorRed,styleDashed);  
Plot(ORBH,"",colorBlue,styleDots);
Plot(ORBL,"",colorBlue,styleDots);


/* Plot Buy and Sell Signal Arrows */
PlotShapes(IIf(Buy, shapeSquare, shapeNone),colorGreen, 0, L, Offset=-40);
PlotShapes(IIf(Buy, shapeSquare, shapeNone),colorLime, 0,L, Offset=-50);
PlotShapes(IIf(Buy, shapeUpArrow, shapeNone),colorWhite, 0,L, Offset=-45);
PlotShapes(IIf(Cover, shapeSquare, shapeNone),colorGreen, 0, L, Offset=-40);
PlotShapes(IIf(Cover, shapeSquare, shapeNone),colorLime, 0,L, Offset=-50);
PlotShapes(IIf(Cover, shapeUpArrow, shapeNone),colorWhite, 0,L, Offset=-45);
PlotShapes(IIf(Sell, shapeSquare, shapeNone),colorRed, 0, H, Offset=40);
PlotShapes(IIf(Sell, shapeSquare, shapeNone),colorOrange, 0,H, Offset=50);
PlotShapes(IIf(Sell, shapeDownArrow, shapeNone),colorWhite, 0,H, Offset=-45);
PlotShapes(IIf(Short, shapeSquare, shapeNone),colorRed, 0, H, Offset=40);
PlotShapes(IIf(Short, shapeSquare, shapeNone),colorOrange, 0,H, Offset=50);
PlotShapes(IIf(Short, shapeDownArrow, shapeNone),colorWhite, 0,H, Offset=-45);

 
//--Restore time frame  
TimeFrameRestore();  
_SECTION_END();

Matrikscesi

Kod:

NewDay:=DAYOFMONTH()<>ref(DAYOFMONTH(),-1) ;   
EndDay:=DAYOFMONTH()<ref(DAYOFMONTH(),1-0) ; 
EntryBufferPct:=0;  SLPct:=0.5;   TargetPct:=3;   MaxTarget: = 100; 
TargetPct:=If(TargetPct = 0, MaxTarget, TargetPct); 
EntryTimeStart :=55;      EntryBarStart:=round(EntryTimeStart/5) - 1;   
EntryTimeEnd:=70;     EntryBarEnd:=round(EntryTimeEnd/5) - 1; 
EntryBarEnd:=If(EntryBarEnd < EntryBarStart, EntryBarStart, EntryBarEnd);
TimeNum:=HOUR()*100+MINUTE();  FirstBarTime:=ValueWhen(1,NewDay,TimeNum);  
EndTime:=ValueWhen(1,EndDay,TimeNum);    SquareOffTime:=EndTime; 
HighestOfDay:=HighestSince(1,NewDay,H);    LowestOfDay:=LowestSince(1,NewDay,L);  
ORBH:=ValueWhen(1,NewDay,HighestOfDay)*(1+(EntryBufferPct/100));  
ORBL:=ValueWhen(1,NewDay,LowestOfDay)*(1-(EntryBufferPct/100));  
BarsSinceNewDay:=BarsSince(NewDay);  
BuySignal:=(H >= ORBH) AND (BarsSinceNewDay  > EntryBarStart);  
ShortSignal:=(L <= ORBL) AND (BarsSinceNewDay  > EntryBarStart) ;  
BarsSinceLastBuySignal:=(BarsSince(Ref(BuySignal,-1)) + 1); 
BarsSinceLastShortSignal:=(BarsSince(Ref(ShortSignal,-1)) + 1); 
BarsSinceLastEntrySignal:=Min(BarsSinceLastBuySignal, BarsSinceLastShortSignal); 
BothEntrySignalsNull:=BarsSinceLastBuySignal<0 AND BarsSinceLastShortSignal<0;
Buy:=(H >= ORBH) AND (BarsSinceNewDay  > EntryBarStart) AND (BarsSinceNewDay <= EntryBarEnd) AND ((BarsSinceNewDay < BarsSinceLastEntrySignal) {OR BothEntrySignalsNull });  
Short:=(L <= ORBL) AND (BarsSinceNewDay  > EntryBarStart) AND (BarsSinceNewDay <= EntryBarEnd) AND ((BarsSinceNewDay < BarsSinceLastEntrySignal) {OR BothEntrySignalsNull} ); 
BuyPrice:=If(Buy, Max(ORBH,O), 0);        ShortPrice:=If(Short, Min(ORBL,Open), 0);   
ORBHSL:=ValueWhen(1,BuyPrice,BuyPrice) * (1-(SLPct/100));   
ORBLSL:=ValueWhen(1,ShortPrice,ShortPrice) * (1+(SLPct/100)); 
ORBHTarget:=ValueWhen(1,BuyPrice,BuyPrice) * (1+(TargetPct/100)); 
ORBLTarget:=ValueWhen(1,ShortPrice,ShortPrice) * (1-(TargetPct/100));
Sell:=(L <= ORBHSL) OR (H >= ORBHTarget)  OR (TimeNum > SquareOffTime-1)  AND (BarsSinceNewDay > BarsSinceLastBuySignal) ;  
Cover:=(H >= ORBLSL)  OR (L <= ORBLTarget)  OR (TimeNum > SquareOffTime-1) AND (BarsSinceNewDay > BarsSinceLastShortSignal) ;  
SellPrice:=If(Sell,If(H >= ORBHTarget, ORBHTarget, Max(ORBHSL, L)), 0);  
CoverPrice:=If(Cover,If(L <= ORBLTarget, ORBLTarget, Min(ORBLSL, H)),0); 
orbBothSides:=If(Buy AND Short, 1, 0);  
Buy:=If(orbBothSides AND C <= O, 0, Buy);  
Short:=If(orbBothSides AND C > O, 0, Short);  
Sell:=If(orbBothSides AND C > O AND (L <= ORBHSL), 1, Sell);  
Sell:=If((BarsSince(Buy) < (BarsSince(Ref(Sell,-1))+1)) OR (BarsSince(Buy) AND (BarsSince(Ref(Sell,-1))<0  ) ),Sell,0); 
Cover:=If(orbBothSides AND C <= O AND (H >= ORBLSL), 1, Cover);  
Cover:=If((BarsSince(Short) < (BarsSince(Ref(Cover,-1))+1)) OR (BarsSince(Short) AND (BarsSince(Ref(Cover,-1)) <0)),Cover,0); 
-Buy*(L-0.2) ;-Sell*(H+0.2);  -Short*(H+0.5); -Cover*(L-0.5);ORBH  ; ORBL

**drkuzn** · 16-03-2017, 00:39

Sn. uufuk, emeğinize, bilginize sağlık. Herşey gönlünüze göre olsun

Konu: Matriks Formülleri

Seçenekler

Başlıklarda Ara

Görünüm

Yer İmleri

Yer İmleri

Gönderi Kuralları