Sayfa 135/135 İlkİlk ... 3585125133134135
Arama sonucu : 1079 madde; 1,073 - 1,079 arası.

Konu: Metastock la ilgili herşey

  1. #1073
     Alıntı Originally Posted by BJK Coccinella Yazıyı Oku
    (CMO(C,p1)+CMO(C,p2)+CMO(C,p3)+CMO(C,p4))/4

    Bu p neyin sabitidir? Bu olmadığı için kodu çalıştıramıyorum?
    Açıklamada diyor ki;

    Hissenin IMKB icindeki goreceli gucunu gosterecek olan system ise asagidaki gibidir, ancak bu sistemi calistirmak icin once IMKB100 endeksi acilarak fare ile secilmelidir, cunku formul icindeki p bileseni son secilmis olan grafik degerlerini ifade eder.

    Endeks grafiğini fare ile işaretleyerek denedim ne explorer ne de indicator builder kabul etmiyor...

  2. #1074
     Alıntı Originally Posted by BJK Coccinella Yazıyı Oku
    (CMO(C,p1)+CMO(C,p2)+CMO(C,p3)+CMO(C,p4))/4

    Bu p neyin sabitidir? Bu olmadığı için kodu çalıştıramıyorum?
     Alıntı Originally Posted by BJK Coccinella Yazıyı Oku
    Açıklamada diyor ki;

    Hissenin IMKB icindeki goreceli gucunu gosterecek olan system ise asagidaki gibidir, ancak bu sistemi calistirmak icin once IMKB100 endeksi acilarak fare ile secilmelidir, cunku formul icindeki p bileseni son secilmis olan grafik degerlerini ifade eder.

    Endeks grafiğini fare ile işaretleyerek denedim ne explorer ne de indicator builder kabul etmiyor...
    Adam akıllı açıklamak istedim;

    Alt Bileşen Adı : SS3x1

    Kod : (CMO(C,p1)+CMO(C,p2)+CMO(C,p3)+CMO(C,p4))/4

    Sistem Adı : SS3

    If(Cross( Fml( "SS3x1") ,0),3,
    If(Cross(0, Fml( "SS3x1")),2,
    If( Fml( "SS3x1")<0,1,4)))

    P değeri pc'de tanımlı değil.

    Başka bir yerde de diyor ki;

    Hissenin IMKB icindeki goreceli gucunu gosterecek olan system ise asagidaki gibidir, ancak bu sistemi calistirmak icin once IMKB100 endeksi acilarak fare ile secilmelidir, cunku formul icindeki p bileseni son secilmis olan grafik degerlerini ifade eder.

    TSI-T1R
    (100*Mov(Mov(Fml("mtmRSC"),20,E),5,E))/(Mov(Mov(Abs(Fml("mtmRSC")),20,E),5,E))

    Bu formulde

    mtmRSC=(C/P)-(Ref(C,-1)/Ref(P,-1))


    Şimdi sorum şu;

    mtmRSC içinde geçen P değerini MetaStock kabul etmesine rağmen neden SS3x1 çalışmıyor?

  3. üstad benim anladığımda şu
    "P" Veri Dizi Tanımlayıcısı

    Özel bir veri dizi tanımlayıcısı (yani, "P" değişkeni), herhangi bir göstergeyi veya fiyat çizelgesini başvurmak için kullanılır. Özel göstergelerle, "P" değişkeni özel göstergenin bırakıldığı çizimi temsil eder.

    Sistem testleri ve keşiflerle, "P" değişkeni seçilen çizimi temsil eder. Bu, bir göstergeyi, keşfi, sistem testini veya uzmanı, grafik tabanlı güvenlikten farklı bir çizimde hesaplamak isterseniz yararlı olabilir.

    "P" değişkenini içeren özel bir göstergeyi yüksek/düşük/kapanış fiyat çubuklarına bıraktığınızda, "P" değişkeni için kapanış kullanılır. Örneğin, aşağıdaki özel gösterge, üzerine bırakıldığı çizimin bir "MACD türü" göstergesini (yani, 12 ve 26 periyotluk üssel hareketli ortalamalar arasındaki farkı) çizer.

    mov( P, 12, E) - mov( P, 26, E)

    Önceden tanımlanmış Birikim/Dağıtım göstergesini çizdikten sonra yukarıdaki özel göstergiyi Hızlı Listeden bırakırsanız, sonuç Birikim/Dağıtım göstergesinin MACD'si olur.

    Elbette, yukarıdaki formülü "P" tanımlayıcısını kullanmadan da yazabilirsiniz, ancak Birikim/Dağıtım'dan farklı bir göstergenin MACD'sini isterseniz bunu değiştirmeniz gerekir. "P" tanımlayıcısını kullanarak, formül daha esnek hale gelir.

    mov( ad(), 12, E) - mov( ad(), 26, E)

    Özel bir göstergedeki YÜKSEK, DÜŞÜK, KAPANIS, HACIM, AÇILIŞ ve AÇIK İLGİ her zaman temel güvenlikten gelir. Örneğin, "YÜKSEK - DÜŞÜK / P" özel göstergesini, grafik tabanlı güvenlik olmayan bir fiyat çizelgesine bıraktığınızda, YÜKSEK ve DÜŞÜK değerler hala temel güvenlikten gelir. "P" değeri, bırakıldığı güvenliğin KAPANIS'ıyı temsil eder.
    algoritma
    Sessiz olursan daha çok şey Duyarsın.

  4. #1076
    Ustam dosyanın sahibi de unutmuş ne yaptığını oradan da cevap yok. Dosya tarihi : 29 Mart 2002

    Yine de teşekkür ederim dosyayı görmeden bu kadar ayrıntılı cevabınız için...

  5. #1077
    "Woodies CCI" MetaStock uyumlu kodunu arıyorum?

  6.  Alıntı Originally Posted by BJK Coccinella Yazıyı Oku
    "Woodies CCI" MetaStock uyumlu kodunu arıyorum?
    ZLR Sell no sidewinder
    ------8<-----------------------------------
    {Woodies Basic ZLR Sell Rules for Metastock}
    {for personal use only}
    {choose number of CCI periods between 2 and 21, 14 is default}
    pds:=Input("CCI periods",2,21,14);

    {standard ZLR Rules i.e.: last 6 CCI bars below the zero line, current bar is less than previous bar and the current cci bar is greater than -130}
    CCI(pds)>-130 AND
    CCI(pds)<Ref(CCI(pds),-1) AND
    Ref(CCI(pds),-1)> Ref(CCI(pds),-2 )AND
    Sum(CCI(pds)<0,6)=6 AND
    Ref(CCI(pds),-1)> -100
    ------8<-----------------------------------


    ZLR Buy no sidewinder
    ------8<-----------------------------------
    {Woodies Basic ZLR Buy Rules for Metastock}
    {for personal use only}
    {choose number of CCI periods between 2 and 21, 14 is default}
    pds:=Input("CCI periods",2,21,14);

    {standard ZLR Rules i.e.: last 6 CCI bars above the zero line, current bar is less than previous bar and the current cci bar is less than 130}
    CCI(pds)<130 AND
    CCI(pds)>Ref(CCI(pds),-1) AND
    Ref(CCI(pds),-1)< Ref(CCI(pds),-2) AND
    Sum(CCI(pds)>0,6)=6 AND
    Ref(CCI(pds),-1)< 100
    ------8<-----------------------------------



    Momentum Reversal Buy with Trend
    ------8<-----------------------------------
    {CCI Basic Momentum Reversal Buy Rules with Trend
    for Metastock}
    {for personal use only}

    {choose number of CCI periods between 2 and 21, 14 is default}
    pds:=Input("CCI periods",2,21,14);
    x:=Sum(CCI(pds)<0,6)=6;
    CCI(pds)>Ref(CCI(pds),-1)AND
    Ref(CCI(pds),-1)< Ref(CCI(pds),-2)AND
    Ref(CCI(pds),-2)< Ref(CCI(pds),-3)AND
    x=0
    ------8<-----------------------------------


    Momentum Reversal Sell with Trend
    ------8<-----------------------------------
    {CCI Basic Momentum Reversal Sell Rules with Trend
    for Metastock}
    {for personal use only}

    {choose number of CCI periods between 2 and 21, 14 is default}
    pds:=Input("CCI periods",2,21,14);
    x:=Sum(CCI(pds)>0,6)=6;
    CCI(pds)<Ref(CCI(pds),-1)AND
    Ref(CCI(pds),-1)> Ref(CCI(pds),-2)AND
    Ref(CCI(pds),-2)> Ref(CCI(pds),-3)AND
    x=0
    ------8<-----------------------------------


    Divergence Setup - useful for developing indicators based on divers, and reverse divers
    ------8<-----------------------------------
    { Class A price/indicator divergence v4 }
    { +1 signal = bullish trough divergences }
    { -1 signal = bearish peak divergences }
    { Copyright 2004 Jose Silva }
    { modified for CCI by cn001532 }
    { For personal use only }
    { nonewww.metastocktools.com }

    {User inputs }
    pds:=Input("Indicator periods",2,50,14);

    {divergence indicator }
    y:=CCI(pds);

    { Price peaks/troughs }
    Pkx:=C<Ref(C,-1) AND Ref(C,-1)>Ref(C,-2)
    AND Ref(C,-1)>=(C+Ref(C,-2))/2;
    Pkx1:=ValueWhen(1,Pkx,Ref(C,-1));
    Pkx2:=ValueWhen(2,Pkx,Ref(C,-1));
    Trx:=C>Ref(C,-1) AND Ref(C,-1)<Ref(C,-2)
    AND Ref(C,-1)<=(C+Ref(C,-2))/2;
    Trx1:=ValueWhen(1,Trx,Ref(C,-1));
    Trx2:=ValueWhen(2,Trx,Ref(C,-1));

    { Indicator peaks/troughs }
    Pky:=y<Ref(y,-1) AND Ref(y,-1)>Ref(y,-2)
    AND Ref(y,-1)>=(y+Ref(y,-2))/2;
    Pky1:=ValueWhen(1,Pky,Ref(y,-1));
    Pky2:=ValueWhen(2,Pky,Ref(y,-1));
    Try:=y>Ref(y,-1) AND Ref(y,-1)<Ref(y,-2)
    AND Ref(y,-1)<=(y+Ref(y,-2))/2;
    Try1:=ValueWhen(1,Try,Ref(y,-1));
    Try2:=ValueWhen(2,Try,Ref(y,-1));

    { Plot signals }
    (Trx AND Try AND Trx1<Trx2
    AND Try1>Try2)
    -(Pkx AND Pky AND Pkx1>Pkx2
    AND Pky1<Pky2)
    ------8<-----------------------------------

    The following code calculates the slope of the 34 ema. This figure does not match the 34 EMA in degrees that we are used to seeing in other Woodie CCI templates but experiment with some values of the slope and you can approximate a "30 degree" angle.

    EMA Slope calculation
    -----8<-------------------------------------------------------------------

    EMA:=Mov(C,34,E);
    EMAprev:=Ref(EMA,-1);

    y:=Min(EMA,EMAprev)/Max(EMA,EMAprev);
    EMAratio:=(If(EMA>EMAprev,2-y,y)-1)*100;
    EMAdeg:=If(EMAratio<0,Atan(EMAratio,1)-360,
    Atan(EMAratio,1)){*10/9}; {<-remove brackets for 0~100% values}

    EMAdeg
    -----8<-------------------------------------------------------------------


    Metastock Pro already has a predefined CCI function. But for those purists who have to see the CCI standard formula expressed in Metastock:
    -----8<-------------------------------------------------------------------
    {CCI-STD cs}
    {written by Corey Saxe}
    V1:=Input("Periods",2,250,14);
    x:=Typical();
    y:=Mov(x,V1,S);
    z:=Sum(Abs(x-LastValue(y+PREV-PREV)),V1)/V1;
    A1:=z*0.015;
    ZZI:=(x-y)/A1;
    ZZI{end}
    -----8<-------------------------------------------------------------------



    {CCI-EquisCustom} Prd:=Input("Periods",2,250,14); X:=Typ(); Y:=X-Mov(X,Prd,S); Yad:=Mov(Abs(Y),Prd,S); Z:=Y/Yad; ZZIe:=(Z/3)*200; ZZIe{end} {CCI-STD cs} {written by Corey Saxe} V1:=Input("Periods",2,250,14); x:=Typical(); y:=Mov(x,V1,S); z:=Sum(Abs(x-LastValue(y+PREV-PREV)),V1)/V1; A1:=z*0.015; ZZI:=(x-y)/A1; ZZI{end} enjoy, Preston
    algoritma
    Sessiz olursan daha çok şey Duyarsın.

  7. #1079
    Teşekkür ederim üstadım aynısını buldum denedim pek verimli olmadı. Ellerin dert görmesin

Sayfa 135/135 İlkİlk ... 3585125133134135

Yer İmleri

Yer İmleri

Gönderi Kuralları

  • Yeni konu açamazsınız
  • Konulara cevap yazamazsınız
  • Yazılara ek gönderemezsiniz
  • Yazılarınızı değiştiremezsiniz
  •